De 60 fichas de nacimientos de una ciudad, se ingresan por teclado los datos de sexo (“V” o “M”) y mes de nacimiento (1 al 12) de cada una. Luego informar: a) Cuántos varones y cuántas mujeres hay. b) Cuántos nacimientos hubo en el primer semestre y cuántos en el segundo c) Porcentaje anual de nacimientos de mujeres

Algoritmo _60Fichasdenacimientos_By_RichardLG

//inico

Definir n,x,mes,v,m,n1,n2 Como Entero;

Definir sexo Como Caracter;

Definir pam Como Real;

n<-60;//cantidad de fichas

x<-1;

//proceso

Mientras x<=n Hacer

Escribir "Ficha de nacimiento: ",x;

Repetir

Escribir Sin Saltar "Ingrese sexo (V/M)...: ";

Leer sexo;

sexo<-Mayusculas(sexo);

Hasta Que sexo=="V" o sexo=="M";

Si sexo=="V" Entonces

v<-v+1;

SiNo

m<-m+1;

FinSi

Repetir

Escribir Sin Saltar "Ingrese mes de nacimiento (1-12)...: ";

Leer mes;

Hasta Que mes>0 y mes<13;

Escribir "";

Si mes>6 Entonces

n2<-n2+1;

SiNo

n1<-n1+1;

FinSi

x<-x+1;

FinMientras

pam<-m/n*100;

//fin

Escribir "";

Escribir "Cantidad de Varones : ",v;

Escribir "Cantidad de Mujeres : ",m;

Escribir "Cantidad de nacimientos primer semestre : ",n1;

Escribir "Cantidad de nacimientos segundo semestre : ",n2;

Escribir "Porcentaje anual de nacimientos de mujeres : ",pam,"%";

FinAlgoritmo